Derivatives of the Riemann xi function at s=1/2

[Jacques Gélinas <jacquesg00@hotmail.com>]

Rick Kreminski computed in 2003 and 2005 highly accurate values of the Stieltjes constants
for (s-1)zeta(s), and from them the even derivatives of xi(s), available in 
          http://faculty.csupueblo.edu/rick.kreminski/stieltjesrelated/xiderest.txt
His Mathematica data files contain an embedded precision estimate, such as

xiderest[490] = 1.98904329578698357865221553147716608602180248569469934098308\
688689767666203002349477596872`77.6054*^80

and can be converted to a format accepted by Pari/GP with
the following sed script (see the appended text file for comments).

# xiderest.sed: Convert a Mathematica data file to PARI/GP format
# Usage: sed --text -f xiderest.sed xiderest > xiderest.gp
/`.*\\$/h;
/`.*\\$/d;
/`\|\\$/!H;
/`\|\\$/!x;
s/\\\n//;
s/`\(.*\)\*^\(.*\)/E\2`\1/;
s/`/; \\\\/;
# End of file xiderest.sed

These values can be verified with the double-exponential integration of Pari/GP,
giving for example the derivative of order 20,000 with 2100 digits on a laptop computer.

Are there other numerical values available ?

Jacques Gélinas, Ottawa

#============================================= xiderest.sed
#
#	Convert a data file from Mathematica to PARI/GP
#
#			xiderest[1] = 0
/ = 0$/d;
#			blank lines
/^.\?$/d;
#			2864824522574683538316274864488477`121\
#			.4772*^75
#		==>	2864824522574683538316274864488477`121.4772*^75
#
#			2864824522574683538316274864488477`121\
#			.069
#		==>	2864824522574683538316274864488477`121.069
/`.*\\$/h;
/`.*\\$/d;
/`\|\\$/!H;
/`\|\\$/!x;
s/\\\n//;
#			688689767666203002349477596872`77.6054*^80
#		==>	688689767666203002349477596872E80`77.6054
s/`\(.*\)\*^\(.*\)/E\2`\1/;
#			14693726641604350416778354683116048`800
#		==>	14693726641604350416778354683116048; \\800
s/`/; \\\\/;

#============================================= end-of-file